CALCULATE

Aplica-se a:Coluna calculadaTabela calculadaMedidaCálculo visual

Avalia uma expressão em um contexto de filtro modificado.

Sintaxe

CALCULATE(<expression>[, <filter1> [, <filter2> [, …]]])

Parâmetros

A expressão que usas como primeiro parâmetro funciona como uma medida.

Os filtros podem ser:

• Expressões de filtro booleano
• Expressões de filtro de tabela
• Funções de modificação do filtro

Quando usas múltiplos filtros, podes avaliá-los usando o AND operador lógico (&&), o que significa que todas as condições devem ser TRUE, ou pelo OR operador lógico (||), o que significa que qualquer uma das condições pode ser verdadeira. Para mais informações, vejaDAX operadores > lógicos de operadores.

Expressões de filtro booleano

Um filtro de expressão booleano é uma expressão que é avaliada como TRUE ou FALSE. Deve seguir várias regras:

• Pode referenciar colunas a partir de uma única tabela.

• Não pode referenciar medidas.

• Não pode usar uma função aninhada CALCULATE .

• Não pode usar funções que escaneiam ou devolvam uma tabela a menos que as passes como argumentos para funções de agregação.

• Pode conter uma função de agregação que devolve um valor escalar. Por exemplo:

  Total sales on the last selected date =
  CALCULATE (
      SUM ( Sales[Sales Amount] ),
      'Sales'[OrderDateKey] = MAX ( 'Sales'[OrderDateKey] )
  )
  

Expressão do filtro de tabela

Um filtro de expressão de tabela aplica um objeto de tabela como um filtro. Pode ser uma referência a uma tabela de modelo, mas é mais provável que seja uma função que retorna um objeto de tabela. Pode usar a FILTER função para aplicar condições complexas de filtro, incluindo aquelas que não pode definir por uma expressão de filtro booleana.

Funções modificadoras de filtro

As funções de modificador de filtro permitem-lhe fazer mais do que simplesmente adicionar filtros. Dão-te controlo extra ao modificar o contexto do filtro.

¹ A função ALL e suas variantes se comportam como modificadores de filtro e como funções que retornam objetos de tabela. Se a sua ferramenta suportar a REMOVEFILTERS função, use-a para remover filtros.

Valor de retorno

O valor que resulta da expressão.

Comentários

• Quando fornece expressões de filtro, a CALCULATE função modifica o contexto do filtro para avaliar a expressão. Para cada expressão de filtro, existem dois resultados padrão quando a expressão do filtro não está envolvida na KEEPFILTERS função:

  • Se as colunas ou tabelas não estiverem no contexto do filtro, novos filtros são adicionados ao contexto do filtro para avaliar a expressão.
  • Se as colunas ou tabelas já estiverem no contexto do filtro, os filtros existentes são sobrescritos pelos novos filtros para avaliar a CALCULATE expressão.

• Usar a CALCULATE função sem filtros atinge um requisito específico. Ele faz a transição do contexto da linha para o contexto do filtro. Esta transição é necessária quando uma expressão (não uma medida do modelo) que resume dados do modelo precisa de ser avaliada no contexto da linha. Esse cenário pode acontecer em uma fórmula de coluna calculada ou quando uma expressão em uma função iteradora é avaliada. Quando usas uma medida de modelo em contexto de linha, a transição de contexto é automática.

• Esta função não é suportada para utilização no modo DirectQuery quando utilizada em colunas calculadas ou regras de segurança ao nível da linha (RLS).

Exemplos

Exemplos neste artigo podem ser usados com o modelo de exemplo do Power BI Desktop do Adventure Works DW 2020. Para obter o modelo, consulte DAX exemplo de modelo.

A seguinte definição de medida de de de vendas produz um resultado de receita, mas apenas para produtos que têm a cor azul.

Blue Revenue =
CALCULATE ( SUM ( Sales[Sales Amount] ), 'Product'[Color] = "Blue" )

A função CALCULATE avalia a soma da tabela Salescoluna Sales Amount em um contexto de filtro modificado. Um novo filtro é adicionado à tabela Produto coluna Cor — ou o filtro substitui qualquer filtro que já tenha sido aplicado à coluna.

A seguinte definição de tabela de de vendas produz uma proporção de vendas sobre vendas para todos os canais de vendas.

Revenue % Total Channel =
DIVIDE (
    SUM ( Sales[Sales Amount] ),
    CALCULATE (
        SUM ( Sales[Sales Amount] ),
        REMOVEFILTERS ( 'Sales Order'[Channel] )
    )
)

A função DIVIDE divide uma expressão que soma da tabela SalesValor de Vendas valor da coluna (no contexto de filtro) pela mesma expressão em um contexto de filtro modificado. É a função CALCULATE que modifica o contexto do filtro usando a função REMOVEFILTERS, que é uma função modificadora de filtro. Ele remove filtros da tabela Ordem de Venda coluna Canal.

A definição de coluna calculada da tabela Cliente a seguir classifica os clientes em uma classe de fidelidade. É um cenário muito simples: quando a receita produzida pelo cliente é inferior a $2500, eles são classificados como Baixo; caso contrário, eles são High.

Customer Segment =
IF (
    CALCULATE (
        SUM ( Sales[Sales Amount] ),
        ALLEXCEPT ( Customer, Customer[CustomerKey] )
    ) < 2500,
    "Low",
    "High"
)

Neste exemplo, o contexto de linha é convertido para o contexto de filtro. É conhecida como transição de contexto. A função ALLEXCEPT remove filtros de todas as colunas da tabela Customer, exceto a coluna CustomerKey.

Conteúdo relacionado

• Filtrar contexto
• Contexto da linha
• CALCULATETABLE Função
• Funções de filtro