WINDOW

Van toepassing op:Berekende kolomBerekende tabelMetenVisuele berekening

Retourneert meerdere rijen die binnen het opgegeven interval zijn geplaatst.

Syntaxis

WINDOW ( from[, from_type], to[, to_type][, <relation> or <axis>][, <orderBy>][, <blanks>][, <partitionBy>][, <matchBy>][, <reset>] )

Parameterwaarden

Retourwaarde

Alle rijen uit het venster.

Opmerkingen

Behalve kolommen die zijn toegevoegd door DAX tabelfuncties, moet elke kolom in relation (wanneer matchBy deze niet aanwezig is) of elke kolom in matchBy en partitionBy (wanneer matchBy aanwezig) een overeenkomstige buitenwaarde hebben om de huidige rij te definiëren waarop moet worden uitgevoerd. Als from_type en to_type beide waarden ABShebben, geldt het volgende alleen voor de partitionBy kolommen:

• Als er precies één overeenkomstige buitenste kolom bestaat, wordt de waarde ervan gebruikt.
• Als er geen corresponderende buitenste kolom bestaat:
  • WINDOW bepaalt eerst alle kolommen die geen corresponderende buitenste kolom hebben.
  • Voor elke combinatie van bestaande waarden voor deze kolommen in WINDOWde bovenliggende context wordt WINDOW geëvalueerd en worden de bijbehorende rijen geretourneerd.
  • WINDOWDe uiteindelijke uitvoer is een samenvoeging van deze rijen.
• Als er meer dan één corresponderende buitenste kolom bestaat, wordt er een fout geretourneerd.

Als alle kolommen van relationzijn toegevoegd door DAX tabelfuncties, wordt een fout geretourneerd.

Als matchBy deze aanwezig is, WINDOW probeert u te gebruiken matchBy en partitionBy kolommen om de rij te identificeren. Als matchBy deze niet aanwezig is en de kolommen die zijn opgegeven binnen orderBy en partitionBy niet uniek kunnen worden geïdentificeerd in elke rij in relation:

• WINDOW probeert het minste aantal extra kolommen te vinden dat nodig is om elke rij uniek te identificeren.
• Als dergelijke kolommen kunnen worden gevonden, WINDOW voegt u deze nieuwe kolommen automatisch toe aan orderByen wordt elke partitie gesorteerd met behulp van deze nieuwe set orderBy-kolommen.
• Als dergelijke kolommen niet kunnen worden gevonden, wordt er een fout geretourneerd.

Er wordt een lege tabel geretourneerd als:

• De overeenkomstige buitenwaarde van een orderBy of partitionBy kolom bestaat niet binnen relation.
• Het hele venster bevindt zich buiten de partitie of het begin van het venster is na het einde.

Als u WINDOW in een berekende kolom die is gedefinieerd in dezelfde tabel als relationen orderBy wordt weggelaten, wordt een fout geretourneerd.

Als het begin van het venster zich vóór de eerste rij bevindt, wordt deze ingesteld op de eerste rij. Als het einde van het venster zich na de laatste rij van de partitie bevindt, wordt deze ingesteld op de laatste rij.

U kunt alleen in visuele berekeningen gebruiken reset en u kunt deze niet gebruiken in combinatie met orderBy of partitionBy. Als reset deze aanwezig is, kunt u opgeven axis maar niet relation.

Als de waarde reset absoluut is (een positief geheel getal of HIGHESTPARENTeen veldreferentie) en de berekening wordt geëvalueerd op of boven het doelniveau in de hiërarchie, wordt de berekening voor elk afzonderlijk element opnieuw ingesteld. Dat wil gezegd, de functie wordt geëvalueerd binnen een partitie die alleen dat specifieke element bevat.

Voorbeelden in dit artikel kunnen worden gebruikt met het voorbeeldmodel Adventure Works DW 2020 Power BI Desktop. Zie DAX voorbeeldmodelom het model op te halen.

Voorbeeld 1: meting

De volgende meting:

3-day Average Price =
AVERAGEX (
    WINDOW (
        -2,
        REL,
        0,
        REL,
        SUMMARIZE ( ALLSELECTED ( 'Sales' ), 'Date'[Date], 'Product'[Product] ),
        ORDERBY ( 'Date'[Date] ),
        KEEP,
        PARTITIONBY ( 'Product'[Product] )
    ),
    CALCULATE ( AVERAGE ( Sales[Unit Price] ) )
)

Retourneert het gemiddelde van 3 dagen van eenheidsprijzen voor elk product. Het 3-daagse venster bestaat uit drie dagen waarop het product verkoop had, niet noodzakelijkerwijs drie opeenvolgende kalenderdagen.

Voorbeeld 2: meting

De volgende meting:

RunningSum =
SUMX (
    WINDOW (
        1,
        ABS,
        0,
        REL,
        ALLSELECTED ( 'Date'[Fiscal Year], 'Date'[Month Number Of Year] ),
        PARTITIONBY ( 'Date'[Fiscal Year] )
    ),
    [Total Sales]
)

Retourneert de lopende som voor de totale verkoop per maandaantal jaar, dat opnieuw wordt gestart voor elk fiscaal jaar:

Voorbeeld 3: visuele berekening

De volgende visuele berekening DAX query:

TotalSalesRunningSumByYear =
SUMX ( WINDOW ( 0, ABS, 0, REL, ROWS, HIGHESTPARENT ), [SalesAmount] )

Retourneert de cumulatieve totale verkoop per maand, berekend over elk jaar. De waarde 1 kan worden gebruikt in plaats van HIGHESTPARENT, met hetzelfde resultaat.

In de onderstaande schermopname ziet u de visualmatrix en de expressie voor de berekening van de visual:

Voorbeeld 4: visuele berekening

De volgende visuele berekening DAX query:

TotalSalesRunningSumByQuarter =
SUMX ( WINDOW ( 0, ABS, 0, REL,, -1 ), [SalesAmount] )

Retourneert de cumulatieve totale verkoop per maand, berekend over elk kwartaal. De waarde LOWESTPARENT kan worden gebruikt in plaats van -1, met hetzelfde resultaat.

Verwante inhoud

• INDEX
• MOVINGAVERAGE
• OFFSET
• ORDERBY
• PARTITIONBY
• RANGE
• RANK
• ROWNUMBER
• RUNNINGSUM